EXCEL / Excel Text Extract Helper

Excel 문자열 추출 도우미

원본과 원하는 문자열로 Excel 버전에 맞는 추출 수식을 만듭니다.

입력값

입력 즉시 계산

최대 2000자 · 현재 19자. 일부 이모지는 2자로 계산합니다.

최대 2000자 · 현재 4자. 일부 이모지는 2자로 계산합니다.

A1에 원본 문자열이 있다고 가정합니다. 첫 번째 일치를 사용하며, 다른 데이터 행에서도 확인해 주세요. 지역 설정에 따라 쉼표 대신 세미콜론이 필요할 수 있습니다.

계산 결과

예상 결과

PD2C
계산 결과
첫 일치 위치4
일치 횟수1

고정 위치 · MID

=MID(A1,4,4)

구분자 기준 · Microsoft 365

=TEXTBEFORE(TEXTAFTER(A1,"-",1),"-")

구분자 기준 · Excel 2016 이상

=MID(A1,FIND("♦",SUBSTITUTE(A1,"-","♦",1))+1,FIND("♦",SUBSTITUTE(A1,"-","♦",2))-(FIND("♦",SUBSTITUTE(A1,"-","♦",1))+1))

안내

A1에 원본 문자열이 있다고 가정하고 원하는 부분 문자열을 얻는 Excel 수식을 제안합니다. 고정 위치와 구분자 패턴을 사용하며, 다른 행에서 같은 규칙이 성립하는지는 직접 확인해야 합니다. 라인 리스트나 자재 목록(MTO)에서 태그의 구역·서비스 코드를 별도 열로 뽑아 정렬하거나 필터할 때 유용합니다.

계산 공식 Formula

고정 위치: =MID(A1,시작위치,글자수)
앞/뒤 추출: LEFT / RIGHT
구버전 구분자: MID + FIND + SUBSTITUTE + LEN
Microsoft 365: TEXTBEFORE + TEXTAFTER

계산 예제 Example

A1이 /P-PD2C-PIPE-BP-033이고 원하는 값이 PD2C라면 =MID(A1,4,4)를 사용할 수 있습니다. Microsoft 365에서는 =TEXTBEFORE(TEXTAFTER(A1,"-",1),"-")가 태그 길이 변경에도 유용합니다. 길이가 행마다 다른 태그에서 마지막 구간(033)만 뽑으려면 Microsoft 365에서는 =TEXTAFTER(A1,"-",-1), 구버전에서는 =RIGHT(A1,LEN(A1)-FIND("@",SUBSTITUTE(A1,"-","@",LEN(A1)-LEN(SUBSTITUTE(A1,"-","")))))를 씁니다. 샘플에서 마지막 하이픈은 16번째라 RIGHT(A1,3)과 같은 결과가 됩니다. 세 번째 구간 PIPE는 =TEXTBEFORE(TEXTAFTER(A1,"-",2),"-")로 얻습니다.

사용 방법

  1. 원본 문자열과 그 안에서 추출할 문자열을 입력합니다. 샘플의 PD2C는 네 번째 위치에서 시작합니다.
  2. Excel 버전을 선택하고, 위치가 일정한 데이터에는 MID를, 태그 길이가 달라지는 데이터에는 구분자 수식을 검토합니다.
  3. 원본은 A1, 복사한 수식은 B1 같은 다른 셀에 넣습니다. 정상 행과 형식이 다른 행에서 모두 결과를 확인합니다.

실무 참고 사항 Engineering notes

  • AI를 사용하지 않습니다. 첫 번째 일치를 기준으로 기본 패턴만 찾으며 반복 값이나 불규칙 데이터의 의미를 추론하지 않습니다.
  • MID·LEFT·RIGHT의 고정 위치 수식은 원본 형식이 달라지면 오동작할 수 있습니다. TEXTBEFORE/TEXTAFTER는 이 도구의 버전 선택 중 Microsoft 365에만 제안됩니다.
  • 구버전 수식의 특수 표식은 샘플 원본에 없는 문자를 선택합니다. 실제 전체 데이터에도 표식이 없는지 확인하세요.
  • 원본과 대상은 각각 최대 2,000자입니다. 일부 이모지는 입력 길이에서 두 글자로 계산됩니다. 대상이 없거나 비어 있으면 원본과 대소문자를 확인하세요.
  • 이모지가 포함된 위치·길이는 워크북의 문자 계산 방식에 맞도록 LEN 식으로 표시될 수 있습니다. TEXTBEFORE/TEXTAFTER는 Excel 2024도 지원하지만 이 도구에서는 365 선택 시 제안합니다.
  • 추출 결과는 텍스트입니다. 숫자로 계산해야 하면 VALUE를 쓰되, 033처럼 앞자리 0이 의미 있는 코드는 텍스트로 두세요.

자주 묻는 질문 FAQ

추출할 문자열이 여러 번 나오면 어떤 것을 사용하나요?

첫 번째 일치와 전체 일치 횟수를 표시합니다. 중복된 태그나 여러 위치에서의 추출은 생성 수식을 검토하고 원하는 발생 순서로 조정해야 합니다.

수식을 붙여 넣었는데 예상한 태그가 나오지 않으면 어떻게 하나요?

A1에 같은 원본이 있는지 먼저 확인하세요. 길이가 달라지는 행에는 고정 위치 수식이 맞지 않을 수 있습니다. 구분자의 종류와 반복 순서를 확인하고, 지역 설정에 따라 인수 구분 쉼표를 세미콜론으로 바꾸세요. 인용부호 안의 쉼표까지 일괄 치환하지 마세요.

행마다 태그 길이가 다르면 어떤 수식이 안전한가요?

고정 위치의 MID보다 구분자 기준 수식이 안전합니다. Microsoft 365에서는 TEXTBEFORE·TEXTAFTER의 몇 번째 구분자(instance_num)를 지정하고, 마지막 구간은 -1을 씁니다. 구버전에서는 SUBSTITUTE로 n번째 구분자를 특수 문자로 바꾼 뒤 FIND로 위치를 찾습니다.

추출 결과에 공백이 섞여 나오면 어떻게 하나요?

원본에 앞뒤 공백이나 연속 공백이 있으면 결과에도 남습니다. =TRIM(수식)으로 감싸거나 원본을 먼저 TRIM한 열을 기준으로 추출하세요.

KEEP WORKING